String sAlarmLRR "LLR Msg: [%s]" (gAlarmPanel) {alarmdecoder="LRR:00#text"}
String sAlarmLRR_lastUser "Last User: [%s]" (gAlarmPanel)
String sAlarmLRR_lastEvent "Last Event: [%s]" (gAlarmPanel)
DateTime sAlarmLRR_lastEventDateTime ""  (gAlarmPanel)
String sAlarmLRR_lastPartition "Last Partition: [%s]" (gAlarmPanel)

import java.util.Map;
import java.util.HashMap;
import com.google.common.collect.ImmutableMap

val Map<String, String> UserList = ImmutableMap.<String, String>builder()
    .put("001", "Installer")
    .put("002", "Master")
    .put("003", "User1")
    .put("004", "User2")
    .build()

rule "LRR Parser"
when
	Item sAlarmLRR received update
then
	var String msg = sAlarmLRR.state.toString();
	var String[] parts = msg.split(",");
	if (parts.length != 3) {
		logError("rules", "sAlarmLRR rule parsing error.");
	} else {
		logInfo("rules", "Parsing sAlarmLRR==> " + msg);
		var String user = UserList.get(parts.get(0));	
		var String partition = parts.get(1);
		var String event = transform("MAP", "alarm_LRR_eventmap.map", parts.get(2).toString);
		
		postUpdate(sAlarmLRR_lastUser, user);
		postUpdate(sAlarmLRR_lastPartition, partition);
		postUpdate(sAlarmLRR_lastEvent, event);
		postUpdate(sAlarmLRR_lastEventDateTime, new DateTimeType());
	}
end